AVR Freaks

An Arduino user will know more about this but I thought there was some mechanism within the FTDI that allowed it to be used to invoke a _RESET in the CPU for purposes of triggering bootloading?

lds		accb, 16    ; Load 16, something-or-other

ldi		accb, 16    ; Load imediated value

;Sunday, October 17, 2010

/*------------------------------------------------------------------------------*/ 
;************ --- ROUTINE TO CONVERT BINARY FORMAT TO BCD FORMAT --- ************/
/*------------------------------------------------------------------------------*/ 

; This routine ("BinToBcd") converts a 16 bit "Binary" number held in a two byte
; variable called "Integer" into a five digit packed "BCD" number.

; The results of the "Binary" to "BCD" conversion is placed into a three byte
; variable called "Result".

; A routine called "BcdToAscii" is then executed where the five digit "BCD" number
; is converted to an "ASCII" string, located in a ten byte RamSpace buffer called
; "AsciiBuff".

; Finally, a routine called "ZeroSupp" is called where the decimal point position
; is set, leading zeros are suppressed and the ASCII string "AsciiBuff" is
; transmitted to the user consol using "USART0_PutString".

; Function name:							->	BinToBcd

; Convert two byte binary integer to 5 ASCII digits and send to terminal

; Registers used:
;						Temp			->	r23
;						acca			->	r24
;						accb 			->	r25
;						XL			->	r26
;						XH			->	r27
;						YL			->	r28
;						YH			->	r29
;						ZL			->	r30
;						ZH			->	r31

; Ram space used:
;				000106	Integer:		.byte 2	->	Integer binary input
;				000108	Result:		.byte 3	->	Packed BCD Result
;				00010b	BCD_Data:	.byte 3	->	Packed BCD output	

; On entry:
;				accb holds the desired decimal point position
;				Integer:Integer+1 -> hold the binary data to be converted to BCD

; On exit:			MS  Byte			 LS  Byte
;				BCD_Data:BCD_Data+1:BCD_Data+2 -> hold the packed BCD data

; Routines called:
;                  			BcdToAscii


BinToBcd:
			push		accb			; Save the cursor position

			ldi		YL, low(Result)	; Get the starting address of Result
			ldi		YH, high(Result)

			ldi		acca, 0x00		;Clear the Result
			std		Y+0, acca
			std		Y+1, acca
			std		Y+2, acca

			ldi		accb, 16
ShftLoop:
			push		accb			; Preserve the bit shift counter
			ldi		YL, low(Result+2)	; Get the last address of Result
			ldi		YH, high(Result+2)
			ldi		accb, 3			; There are 3 Result bytes to be processed
			ldd		acca, Y+0		; Get current byte to be converted
BcdLoop:
			push		accb			; Preserve the byte counter
			mov		accb, acca		; Transfer acca to accb -> Preserve acca
			andi		acca, 0x0F		; Clear the high nibble
			subi		acca, 0x05		; Check for improper BCD digit
			brmi		AT			; Is this a good BCD digit ?
			
			ldi		Temp, 0x03			
			add		accb, Temp
AT:
			mov		acca, accb		; Transfer accb to acca -> recover acca
			andi		acca, 0xF0		; Clear the low nibble
			subi		acca, 0x50		; Check for improper BCD digit
			brmi		BT			; Is this a good BCD digit

			ldi		Temp, 0x30
			add		accb, Temp		; No! Correct the displaced bits
BT:
			std		Y+0, accb		; Store the data at the current address

			pop		accb			; Recall the byte counter
			dec		accb			; Have we 3 bytes?
			brne		NoResult
			rjmp		ResultDone
NoResult:
			ld		acca, -Y		; Get next byte and decrement address pointer			
			rjmp		BcdLoop
ResultDone:
			ldi		ZL, low(Integer)	; Get the starting address of Integer
			ldi		ZH, high(Integer)
			ldi		YL, low(Result)	; Get the starting address of Result
			ldi		YH, high(Result)

			ldd		acca, Z+1
			lsl		acca			; Shift to set up for the next conversion
			std		Z+1, acca
			ldd		acca, Z+0
			rol		acca
			std		Z+0, acca
			ldd		acca, Y+2
			rol		acca
			std		Y+2, acca
			ldd		acca, Y+1
			rol		acca
			std		Y+1, acca
			ldd		acca, Y+0
			rol		acca
			std		Y+0, acca

			pop		accb			; Recall the bit shift counter
			dec		accb
			brne		ShftLoop		; Have we looped 16 bit shifts ?

			lds		acca, Result
			sts		BCD_Data, acca
			lds		acca, Result+1
			sts		BCD_Data+1, acca
			lds		acca, Result+2
			sts		BCD_Data+2, acca

			pop		accb			; Recover the decimal point position
	 		rcall		BcdToAscii

			ret