AVR Freaks

If my memory is correct,  the little Red or Blue ST7735 displays from Ebay do not have a MISO pin.  So you can't read the memory.

If you have a ST7735 with a parallel bus,  you probably can read the ID and memory.    But you use a lot of wires for a 128x160 display.

David.

I cannot remember. But the Data sheet will tell you if your SPI interface can be read.

It also depends on which IM# pins are made available from the module.

David.

Ah-ha.   I had always just assumed that the Ebay modules were write-only.

Looking at "13.3.10 4-Line serial MCU Interface (IM2, IM1, IM0=”000”, SPI4W=1)"in theST7735R data sheet,   I see that SDA is bi-directional.   So you send a hardware 8-bit command,  disconnect SPI,  make MOSI input-pull-up and bit bash the read.

It had never crossed my mind to try it.   I will give it a go and see how I get on.

I tried reading SDA on a HX8347D a couple of days ago without success.

Woo-hoo,  I will dig out the Arduino sketch.  If it works on the ST7735R,  I will try a ILI9163.

David.

Edit.  I tried with both ST7735R with "almost" success.  

I have read my ST7735R and ILI9163C controllers:

// see if 4-line mode can read anything

#define TFT_DC  (9)     //DC=7 for HX8347
#define TFT_RESET (8)   //Backlight on HX8347
char *chip = "controller";

// use SPI mode #0
uint32_t readwrite8(uint8_t cmd, uint8_t bits, uint8_t dummy)
{
    uint32_t ret = 0;
    uint8_t val = cmd;
    int cnt = 8;
    digitalWrite(SS, LOW);
    digitalWrite(TFT_DC, LOW);
    pinMode(MOSI, OUTPUT);
    for (int i = 0; i < 8; i++) {   //send command
        digitalWrite(MOSI, (val & 0x80) != 0);
        digitalWrite(SCK, HIGH);
        digitalWrite(SCK, LOW);
        val <<= 1;
    }
    if (bits == 0) {
        digitalWrite(SS, HIGH);
        return 0;
    }
    pinMode(MOSI, INPUT_PULLUP);
    digitalWrite(TFT_DC, HIGH);
    for (int i = 0; i < dummy; i++) {  //any dummy clocks
        digitalWrite(SCK, HIGH);
        digitalWrite(SCK, LOW);
    }
    for (int i = 0; i < bits; i++) {  // read results
        ret <<= 1;
        if (digitalRead(MOSI)) ret |= 1;;
        digitalWrite(SCK, HIGH);
        digitalWrite(SCK, LOW);
    }
    digitalWrite(SS, HIGH);
    return ret;
}

void showreg(uint8_t reg, uint8_t bits, uint8_t dummy)
{
    uint32_t val;
    val = readwrite8(reg, bits, dummy);

    Serial.print(chip);
    Serial.print(" reg(0x");
    if (reg < 0x10) Serial.print("0");
    Serial.print(reg , HEX);
    Serial.print(") = 0x");
    if (val < 0x10) Serial.print("0");
    Serial.println(val, HEX);

}

void setup() {
    // put your setup code here, to run once:
    uint32_t ID = 0;
    Serial.begin(9600);
    Serial.println("Bi-directional Read registers");
    digitalWrite(SS, HIGH);
    //    digitalWrite(SCK, HIGH);
    pinMode(SS, OUTPUT);
    pinMode(SCK, OUTPUT);
    pinMode(MOSI, OUTPUT);
    pinMode(MISO, INPUT_PULLUP);
    pinMode(TFT_DC, OUTPUT);
    pinMode(TFT_RESET, OUTPUT);
    digitalWrite(TFT_RESET, HIGH);
    digitalWrite(TFT_RESET, LOW);   //Hardware Reset
    delay(50);
    digitalWrite(TFT_RESET, HIGH);
    showreg(0x01, 0, 0);            //Software Reset
    delay(100);
    ID = readwrite8(0x04, 24, 1);
    if (ID == 0x7C89F0uL) chip = "ST7735R";
    if (ID == 0x548066uL) chip = "ILI9163C";
    showreg(0x04, 24, 1);   //RDDID
    showreg(0x09, 32, 1);   //RDSTATUS
    showreg(0x0A, 8, 0);
    showreg(0x0B, 8, 0);
    showreg(0x0C, 8, 0);
    showreg(0x0D, 8, 0);
    showreg(0x0E, 8, 0);
    showreg(0x0F, 8, 0);
    showreg(0x2E, 24, 8);   //readGRAM
    showreg(0xDA, 8, 0);
    showreg(0xDB, 8, 0);
    showreg(0xDC, 8, 0);
}

void loop() {
    // put your main code here, to run repeatedly:

}

The RDIDD and Status Registers require one dummy clock when you use 4-wire Serial.    No problem.   You have to bit bash it on an AVR because it has not got a SDIO capability.   So it does not matter if you have to do a few shenanegins.

You can see that I read the GRAM with register 0x2E.

Now that I can readGRAM(),  I will implement readPixel() for these two controllers.

David.

That sounds possible, but you need to think about the other devices on the SPI bus.
I will link MOSI, MISO with a 10k resistor. Send spi(cmd), make MOSI an input, and receive replies from spi(0xFF).

Yes, read 4 bytes for RDDID. Read 5 bytes for RDSTATUS. Shift by 1.
I will try this later. I can see that 8MHz reads might be iffy. It always amazes me just how fast these controllers can handle SPI. You do need to be careful with the Parallel bus. Reads are always slower than Writes.

David.

Sitronix and Ilitech are two different companies.

All TFT controllers are similar in operation. It is the differences that you need to worry about.

If I was you, I would look at the API of current libraries. Life is a lot easier if you use the same method()s. e.g. look at Adafruit classes.

I have a single readGRAM() method. readPixel() is just the special case of a block with size of one.

David.

Your code looks fine to me. Let's face it. The only Arduinoese is the pinMode and digitalRead and write.

I suggest that you put your delay and linefeeds into the showreg() function. Then you will have exactly the same structure as me.

You do realise that buying a 3.3V capable Arduino clone is the next best investment you can make (after buying some pencils)

David.

As I suggested.   Tidy up your "port".

I gave you an Arduino example because the whole world can use it.

If you have your own custom display functions,  it is up to you to debug them.

David.

Yes, of course I ran it in real life.

While I was out with my dog, I realised that you had deliberately removed my hardware reset. Most modules do NOT have pull-ups on their pins. You need to have a pull-up on RST pin or else the controller will not know where it is.
You can avoid the active-low on RST by using software reset.

David.

What hardware are you using?
i
I have definitely got a C project for Codevision.
I would prefer to post an Arduino library solution.

David.

I bit bashed it in C at an effective 1.5Mhz. I know that I can get faster with unrolled ASM.

If I am feeling keen, I will update a C++ library and incorporate the extra methods.

I strongly recommend that you get a 3.3V Arduino. You don't have to use it in a final project but it is excellent for broadcasting code that the whole world can use.
And a $10 Saleae clone does not break the bank.

David.

I have the regular Ebay modules.   They are 3.3V operation (but Ebay vendors lie through their teeth about 5V)

I use them with ARM which is 3.3V or with a Seeeduino which is a "3.3V switchable" Duemilanove clone.

Life is far simpler with an MCU that runs at 3.3V.    Level shifting buffers that are unidirectional are just fine.    When you want individual pins to be bi-directional,  you have to think harder.

Why don't you buy a couple of Red modules from China?   128x160 is ST7735R and 128x128 is ILI9163C.

Why not hack your current module?    Just run a wire from the module's SDA pin to a GPIO pin on the AVR via a 1k series resistor.    You may get glitches but hey-ho,  it is worth  a try.

David.

I have software scrolling working on ST7735 and ILI9361. It is SLOW. It is also a bit iffy.
When you do an animated scroll, you are doing multiple readGRAM calls. This increases the chance of a single bit going wrong.

The ST7735 data sheet does not seem to show hardware vertical scrolling. It seems to work fine but I have not done extensive tests of subwindows.

So if you want horizontal scrolling, life would be a lot simpler if you just used Landscape.

David.

Yes,   you read 3 bytes :

int16_t ST7735_kbv::readGRAM(int16_t x, int16_t y, uint16_t * block, int16_t w, int16_t h)
{
	uint8_t r, g, b;
	int16_t n = w * h;    // we are NEVER going to read > 32k pixels at once
	setAddrWindow(x, y, x + w - 1, y + h - 1);
	CS_ACTIVE;
	WriteCmd(ST7735_RAMRD);
	CD_DATA;
	SDIO_INMODE();        // do this while CS is Active

	r = readbits(9);	  // needs 1 dummy read (8) for ILI9163
	while (n-- > 0) {
		r = readbits(8);
		g = readbits(8);
		b = readbits(8);
		*block++ = color565(r, g, b);
	}
	CS_IDLE;
	SDIO_OUTMODE();      //do this when CS is Idle
    setAddrWindow(0, 0, width() - 1, height() - 1);
    return 0;
}

The readbits():

#define SDIO_INMODE() uint8_t spcr = SPCR;SPCR = 0;MOSI_IN   //no braces
#define SDIO_OUTMODE() {MOSI_OUT;SPCR = spcr;}
static uint32_t readbits(uint8_t bits)
{
	uint32_t ret = 0;
	while (bits--) {
		ret <<= 1;
		if (PINB & (1<<MOSI_PIN)) ret++;
		SCK_HI;
		SCK_LO;
	}
	return ret;
}

I am sure that you can work out what the macros do.

Most "readable " registers are 8-bit.   Specials for RDDID and RDSTATUS:

static uint32_t readRegister(uint8_t reg)
{
    uint32_t ret;
	uint8_t bits = 8;
	if (reg == 4) bits = 25;
	if (reg == 9) bits = 33;
    CS_ACTIVE;
    WriteCmd(reg);
    CD_DATA;                    //
	SDIO_INMODE();
    ret = readbits(bits);
    CS_IDLE;
	SDIO_OUTMODE();
    return ret;	
}

David.

Do you have ST7735R or ST7735S ?

The S can do Vertical Scroll.   The R can not.

Both variants can read certain registers via the bidirectional SDA line.

What is a XMC4800?   Does it have DDRB, PORTB, PINB registers?   or equivalents?

David.

Post your code.  Or at least study the code that I posted.

You must change the SDA data direction from write to read after you have written the command.

To be honest,   the risetime of the green trace does look as if you have changed SDA to "INPUT_PULLUP" at the time DC goes fom command to data.

David.

What value is your external pullup on SDA ?   I would use 10k - 47k.

I am not familiar with your MCU or the syntax in your code.   As you can see by the Timing Diagrams,   the DC state must be 0 when the last SCK pulse is sent (lsb of the command)

Your yellow trace shows that DC=0 when the green trace rises (entering hi-Z).   So the Timing looks correct to me.

I can post you an Arduino sketch that bit-bashes the ST7735.    Do you possess a 3V Arduino like Zero or Due ?

David.

Edit.   Silly question:  Have you got TFT_RST pin high?   Nothing will work when the controller is in reset.

4k75 sounds rather an unusual value.   It does seem rather "strong".

When you have a bidirectional SDA pin,  the "output" drive tends to be a bit wimpy.

It may be a weak push-pull.   It is more likely to be a "common-drain" style.

The AVR internal pullup is about 30k.   I could try a strong external pullup to see what happens with ST7735S, ILI9163C, ...

I suggest that you try 22k first.

Yes,  you would use a hardware reset first.  e.g. 1ms active low pulse.   Then wait 120ms for the ST7735 to complete its internal reset before sending any commands.   

David.

I am a little horrified by the ringing on your signals.   I would try to clean this up first.

The XMC4800 seems to be a 144MHz Cortex-M4.    I see no reason for why it should not work ok with a ST7735.

I have run a ST7735S with 100Mhz M4 from ST and 96MHz M4 from Freescale.

Mind you,  this is supposed to be an "Atmel/Microchip" forum.

I would also suggest that an Arduino or MBED platform would be a wise investment.    It would mean that you could run example sketches from anyone, anywhere in the world.    Ok,   it might be on different target processors.

So my only advice is:

1.  buy a 3.3V Arduino / MBED

2.  run / study / investigate example code.

3.  reproduce the code / algorithms on your XMC4800.

In practice,   I read the ID from a ST7735 or ILI9163 to select the correct initialisation sequence.

I use the same graphics etc for any controller.    Occasionally I read blocks of GRAM memory.  e.g. to manipulate or save an area of screen.

David.

Rubbish.   I have read GRAM and the ID registers of the ILI9163C for always.

I have also published a diagnostic sketch for the Arduino.   And there is example code in #13.

David.