AVR Freaks

Yes it's a small program, the exercise is to set up timers and interrupts as well as ADC and output to DAC.

So erased, does that mean that the program doesn't use them by my code and hence it doesn't matter what is in them? Cause I tried to hard code a small line that would just change a DDR register to 0b10101010 just to see if it would set it when simulating but nothing happens to the program flash when I try to step through the program.
Have a made some stupied coding error or do you know what I should do to be able to simulate again?

My code:

.NOLIST
.INCLUDE "m328pdef.inc"
.LIST

.DEF temp = r16                ; Temporary variable


; Define variables stored in SRAM
.DSEG
.ORG 0x0100
DAC_ONOFF: .BYTE 1            ; Store DAC ON/OFF
MUX_CHANNEL: .BYTE 1        ; Store analog channel


.CSEG
; Program reset
.ORG 0
    rjmp RESET

; Interrupt PCINT0
.ORG 0x0006
    rcall pinInterrupt

; Interrupt timer0 compare match A
.ORG 0x001C
    rcall timerInterrupt


.ORG 0x033
RESET:
    ldi temp, LOW(RAMEND)    ; Initalize
    out SPL, temp            ; stack pointer
    ldi temp, HIGH(RAMEND)    ; to RAMEND
    out SPH, temp            ;
    ldi temp, 0x00            ;
    sts MUX_CHANNEL, temp    ; Select analog channel ADC0
    cli                        ; Turn off interupts
    rcall initDAC            ; Initalize DAC
    rcall initADC            ; Initalize ADC
    rcall initTimer            ; Initalize timer
    rcall initPCINT0        ; Initalize external interrupt
    sei                        ; Turn on interupts

busyWait:
    ldi r18, 0xff
    out PORTB, r18
    rjmp busyWait


;--------------------------------------------------- 
; pinInterrupt: Read PINB0 and toggle DAC ON/OFF.
;                If PINB0 = 1, DAC is ON.
;                If PINB0 = 0, DAC is OFF.
;   
; Input: None.
; Output: None.
; Sideeffects: None.
; Registers affected: None.
;--------------------------------------------------- 
pinInterrupt:
    push r18                ; Save environment
    push r19
    in r19, SREG

    in r18, PINB0            ; Read PINB0
    cpi r18, 1<<PINB0        ; Compare if 1
    brne DACOFF                ; If 0, branch to label
    ldi r18, 0b1            ; Toggle ON
    rjmp pinEnd
    
DACOFF:
    ldi r18, 0b0            ; Toggle OFF
    
pinEnd:
    sts DAC_ONOFF, r18        ; Store ON/OFF in SRAM
    out SREG, r19            ; Restore environment
    pop r19
    pop r18

    reti                    ; Return from interrupt

;--------------------------------------------------- 
; timerInterrupt: Sample ADC by calling inADC8 subroutine and output
;                  value to PORTB by calling outDAC subroutine.
;                  No output to PORTB is DAC is toggled OFF.
;   
; Input: None.
; Output: None.
; Sideeffects: None.
; Registers affected: None.
;--------------------------------------------------- 
timerInterrupt:
    push r18                ; Save environment
    push r19
    in r19, SREG
    
    rcall inADC8            ; Read ADC

    lds r18, DAC_ONOFF        ; Load DAC ON/OFF from SRAM
    cpi r18, 0b1            ; Compare if ON
    brne timerDACOFF
    rcall outDAC            ; Output ADC conversation to DAC
    rjmp timerEnd


timerDACOFF:
    ldi r20, 0x00            ; No output to DAC
    rcall outDAC


timerEnd:    
    out SREG, r19            ; Restore environment
    pop r19
    pop r18

    reti                    ; Return from interrupt

;--------------------------------------------------- 
; initTimer: Initalize timer 0 with compare match A interupts.
;             The timer is set with a prescaling factor of 8.
;             The compare value is set to 0x0F.
;   
; Input: None.
; Output: None.
; Sideeffects: None.
; Registers affected: TCCR0A, TCCR0B, TIMSK0 and OCR0A
;--------------------------------------------------- 
initTimer:
    push r16                        ; Save enviornment
    ldi r16, 1<<WGM01                
    out TCCR0A, r16                    ; Clear timer on compare Match
    ldi r16, 1<<CS01                 
    out TCCR0B, r16                    ; Set prescaler to 8
    ldi r16, 0x0F                    
    sts OCR0A, r16                    ; Set compare value to 0x0F
    ldi r16, 1<<OCIE0A                
    sts TIMSK0, r16                    ; Enable Timer0 compare match A 
    pop r16                            ; Restore environment

    ret                                ; return from subroutine

;---------------------------------------------------------------------
; initPCINT0: Set PINB0 to be read, enable interrupts triggered by voltage change
;              at PINB0.
;   
; Input: None
; Output: None
; Sideeffects: None
; Registers affected: PCICR and PCMSK0
;---------------------------------------------------------------------- 
initPCINT0:
    push r16                ; Save environment
    ldi r16, 1<<PCIE0 
    sts PCICR, r16            ; Pin change interrupt enable 0
    ldi r16, 1<<PCINT0         
    sts PCMSK0, r16            ; Enable interrupt on PINB0
    pop r16                    ; Restore environment

    ret                        ; Return from subroutine

;---------------------------------------------------------------------
; initDAC: Initalizes PortD to output.
;   
; Input: None
; Output: None
; Sideeffects: None
; Registers affected: DDRD
;---------------------------------------------------------------------- 
initDAC:
    push r18
    ldi r18, 0xFF            ; Set PortD
    out DDRD, r18            ; to output
    pop r18

    ret                        ; Return from subroutine

;---------------------------------------------------------------------
; initADC: Initalize and set up ADC to free-running mode. The ADC will
;           have a reference voltage AVcc. The result will be left adjusted
;           and have a 8-bit precision.
;           The ADC will only read the input from channel 0.
;           Frequency of samples: 8MHz
;
;           Hardware: Set external capacitor at AREF pin
;   
; Input: None
; Output: None
; Sideeffects: None
; Registers affected: ADMUX and ADCSRA
;---------------------------------------------------------------------- 
initADC:
    push r18
    ldi r18, (0<<REFS1) | (1<<REFS0) | (1<<ADLAR)        ; Set reference voltage to AVcc and
    sts ADMUX, r18            ; set the result to be left adjusted
    ldi r18, 1<<ADEN        ; ADC enable, 
    sts ADCSRA, r18            ; sample division factor set to 2
    pop r18

    ret                        ; Return from subroutine

;---------------------------------------------------------------------
; inADC8: Reads data from ADC pins.
;   
; Input: MUX-channel from SRAM
; Output: Result from ADC stored in register r20
; Sideeffects: 
; Registers affected: r20
;---------------------------------------------------------------------- 
inADC8:
    push r18                ; Save environment
    push r19                ;
    in r19, SREG            ;
    
    lds r18, ADMUX            ; Set analog channel without
    andi r18, 0b11110000    ; effecting bit 7:4
    lds r19, MUX_CHANNEL    ; Load analog channel from SRAM
    or r18,    r19                ; 
    sts ADMUX, r18            ; Store selected channel
    
    lds r18, ADCSRA            ; Start conversation
    ori r18, 0b01000000        ;
    sts ADCSRA, r18            ;


checkInteruptFlag:
    lds r18, ADCSRA            ; Store bits from ADCSRA and
    andi r18, 0b00010000    ; check interupt flag if
    cpi r18, 0b00010000        ; conversation is done
    brne checkInteruptFlag    ; 
    lds r20, ADCH            ; Read result from ADC
    out SREG, r19            ; Restore environment
    pop r19
    pop r18

    ret                        ; Return from subroutine

;---------------------------------------------------------------------
; outDAC: Output result from read ADC pins.
;   
; Input: r20
; Output: None
; Sideeffects: None
; Registers affected: None.
;---------------------------------------------------------------------- 
outDAC:
    out PORTD, r20            ; Output the result

    ret                        ; Return from subroutine

This is an exercise for a course I read 1 and a half years ago and I got a return on this one, which I need to fix to get the points be able to write my master's thesis in spring. I just haven't coded in assembler and used Atmel studio since then so I had forgotten a lot of it.

Wow thank you, I tried increasing the compare match as well as clicking under the interrupt label, "run to curser", and it it took 2100 clock cycles to get there - but it get's there!