AVR Freaks

But your code use LPM. (the good old way).

OP wants to use flash that is memory mapped.

Maybe I'm missing something, but I don't see the advantage of putting anything in a C file here.

Why is that better than:

F_DATASTR1:  .DB "STRING1",$0a
F_DATASTR2:  .DB "STRING2",$0a
F_DATASTR3:  .DB "STRING3",$0a
F_DATASTR4:  .DB "STRING4",$0a

GermanFranz's method seems reasonable to me, but I would use a macro instead of manually creating two separate labels DATASTR and F_DATASTR.

.macro ldx
        ldi     XL,low((@0*2)-$10000)
        ldi     XH,high((@0*2)-$10000)
.endmacro

That's pretty clean, but it's a bit chip-specific.

I did a bit of work to make the macros more general, so that they can be used on other chips without modification.

I THINK these should work ok on everything form ATmega808 to AVRxxxDyzz; I added a macro "lastFlashData" to transparently do the .org to the "last page" of flash...

(tested by object code inspection, though...)

;
; mappedflash.asm
;
; Created: 12/20/2021 12:49:00 AM
; Author : billw
; Released to the public domain

.macro lastFlashData
; Arguments: None
; Set the location (.org) to the last page of mappable flash.
; This is either the last PROGMEM_SIZE bytes of flash, or just
; the current location (if some code already occupues that page)
; this should work with parts that can map ALL their flash into
; the data space, or parts that can only map 32k.
;
.cseg   ; make sure we're in "code" memory.
.if (((PROGMEM_END+1) - MAPPED_PROGMEM_SIZE)/2) > PC
; if code has NOT encroached on the last mappable window of flash
;   then put flash data in that last page.
.org (FLASHEND+1) - (MAPPED_PROGMEM_SIZE/2)
.endif
; if code DOES use last page, just continue flash data at .
.endm

.macro ldxmf  ; load X from mapped flash
; Arguments: <flashaddr>
;  load the address of the label into X.
;  The label should be in cseg, within the section of flash that
;  is mapped to the "mapped flash" section of the data space.
;  (actually setting up the mapping must be done elsewhere.)
;
        ldi     XL,low((@0*2))
        ldi     XH,high(MAPPED_PROGMEM_START + ((@0*2) & (MAPPED_PROGMEM_START-1)))
.endmacro

.macro ldymf  ; load Y from mapped flash
; Arguments: <flashaddr>
;  load the address of the label into Y.
        ldi     YL,low((@0*2))
		ldi     YH,high(MAPPED_PROGMEM_START + ((@0*2) & (MAPPED_PROGMEM_START-1)))
;        ldi     YH,high((@0*2) & 0xFFFF)
.endmacro

.macro ldzmf  ; load Z from mapped flash
; Arguments: <flashaddr>
;  load the address of the label into Z.
        ldi     ZL,low((@0*2))
		ldi     ZH,high(MAPPED_PROGMEM_START + ((@0*2) & (MAPPED_PROGMEM_START-1)))
.endmacro

.macro ldsmf  ; load register direct from mapped flash (LDS)
; Arguments: <register>, <flashaddr>
	  lds @0, MAPPED_PROGMEM_START + (((@1)*2) & (MAPPED_PROGMEM_START-1))
.endm

.macro ldsmfo ; load register direct form mapped flash, with offset.
; Arguments: <register>, <flashaddr>, <offset>
; this permits loading a byte from an odd flash address (since all cseg
;   labels are even address (word addressing)
	  lds @0, MAPPED_PROGMEM_START + ((@2+((@1)*2)) & (MAPPED_PROGMEM_START-1))
.endm

.cseg
.org 0
vectors:
    rjmp start
    rjmp noint
noint: rjmp noint

.listmac

; test cases
start:
	ldxmf mystring
    ldymf otherst
	ldzmf s1
	ldsmf r1, d1
	ldsmfo r2, d1, 1
	rjmp start

fdata:
	lastFlashData
    d1: .db 1,2,3,4
    s1: .db "string",0,0
	mdata: .dd 0x1234, 0xdeadbeef, 0, 1, 2, 3, 6789
	mystring: .db "hello world\n"
	otherst: .db "another string"