AVR Freaks

I guess the big question is what made you put the DATA at the start, not the end in the first place? The original file could have just been:

;
; opg5_2.asm
;
; Created: 04-03-2018 16:50:06
; Author : Martin Androvich
;

; ** Hard coded variables:
DEFINITIONS:
	.DEF	COUNTER			= R22
	.DEF	TIMERMODE		= R23
	.DEF	SEQ_LEN			= R24
	.SET	SEQUENCE		= SEQUENCE_2 ; NOT WORKING :8
	.SET	SEQUENCE_LEN	= 9


; ** Initialize program:
INIT:

	; Initiate Stack

	LDI 	R16, HIGH(RAMEND) 	
	OUT 	SPH, R16 			
	LDI 	R16, LOW(RAMEND)		
	OUT 	SPL, R16 
	
	; 7-Segment Display (PortB)

	LDI		R16, 0xFF				; Load HIGH into R16
	OUT		DDRB, R16				; Set PortB as Output
	LDI		R16, 0xFF				; Turn off Display
	OUT		PORTB, R16				; ^

	; Switches (PortC)

	LDI		R16, 0x00				; Load LOW into R16
	OUT		DDRC, R16				; Set PortC as Input
	LDI		R16, 0xFF				; Load HIGH into R16
	OUT		PORTC, R16				; Use PortC with Intern Pull-Up Resistor

	; Various

	LDI		R16, 0xFF
	LDI		COUNTER, 0
	LDI		TIMERMODE, 0b0101		; Default Prescaler = 1024

	RJMP	CHECKINPUT_SPEED		; Jump to input loop

; ** Main loop:
MAIN:
	LPM		R16, Z
	OUT		PORTB, R16

	RCALL	DELAY					; Call Delay Timer

	CP		COUNTER, SEQ_LEN		; Check if counter > allowed length
	BREQ	INIT
	
	ADIW	ZH:ZL, 1				; Increment Z Pointer
	INC		COUNTER					; Increment Counter

	RJMP	MAIN

CHECKINPUT_SPEED:
	IN		R16, PINC				; Read PINC into R16
	COM		R16						; Compensate for Active Low
	ANDI	R16, 0x0F				; Mask for prescaler comparisons (LOW NIBBLE)

	LDI		TIMERMODE, 0b0010		; Prescaler: 8
	CPI		R16, 0b00000001
	BREQ	CHECKINPUT_SEQEUNCE

	LDI		TIMERMODE, 0b0011		; Prescaler: 64
	CPI		R16, 0b00000010
	BREQ	CHECKINPUT_SEQEUNCE

	LDI		TIMERMODE, 0b0100		; Prescaler: 256
	CPI		R16, 0b00000100
	BREQ	CHECKINPUT_SEQEUNCE

	LDI		TIMERMODE, 0b0101		; Prescaler: 1024
	CPI		R16, 0b00001000
	BREQ	CHECKINPUT_SEQEUNCE

	RJMP	CHECKINPUT_SPEED		; Loop until speed selected (input entered)

CHECKINPUT_SEQEUNCE:
	IN		R16, PINC				; Read PINC into R16
	COM		R16						; Compensate for Active Low
	ANDI	R16, 0xF0				; Mask for sequence comparisons (HIGH NIBBLE)

	LDI		ZH, HIGH(SEQUENCE_1*2)	; Set SEQUENCE_1
	LDI 	ZL, LOW(SEQUENCE_1*2)	; 
	LDI		SEQ_LEN, 9				; 
	.SET	SEQUENCE_LEN	= 9		; NOT WORKING

	CPI		R16, 0b10000000
	BREQ	MAIN

	LDI		ZH, HIGH(SEQUENCE_2*2)	; Set SEQUENCE_2
	LDI 	ZL, LOW(SEQUENCE_2*2)
	LDI		SEQ_LEN, 5

	CPI		R16, 0b01000000
	BREQ	MAIN

	LDI		ZH, HIGH(SEQUENCE_3*2)	; Set SEQUENCE_3
	LDI 	ZL, LOW(SEQUENCE_3*2)
	LDI		SEQ_LEN, 7

	CPI		R16, 0b00100000
	BREQ	MAIN

	RJMP	CHECKINPUT_SPEED		; Loop until sequence selected (input entered)

; ** Timer0 Delay Function:
DELAY:
	LDI		R20, 0
	OUT		TCNT0, R20				; Clear timer

	OUT		TCCR0, TIMERMODE		; Start timer  (Normal mode, internal clock, prescaler: VAR)
AGAIN:
	IN		R20, TIFR
	SBRS	R20, TOV0				; Check if Timer0 overflow flag is shown
	RJMP	AGAIN					; Repeat

	LDI		R20, 0
	OUT		TCCR0, R20				; Stop timer
	LDI		R20, (1<<TOV0)
	OUT		TIFR, R20				; Clear overflow flag by writing 1 to TIFR
	RET

SEQUENCE_1:

	.DB 	0b10100000, 0b11110011	; 0 and 1
	.DB 	0b10010100, 0b10010001	; 2 and 3
	.DB 	0b11000011, 0b10001001	; 4 and 5
	.DB 	0b10001000, 0b10110011	; 6 and 7
	.DB 	0b10000000, 0b10000011	; 8 and 9

SEQUENCE_2:

	.DB 	0b00111111, 0b01110111	; D6 and D3
	.DB 	0b01111011, 0b01111101	; D2 and D1
	.DB 	0b01111110, 0b01101111	; D0 and D4

SEQUENCE_3:

	.DB 	0b01001000, 0b00100000	; 8 & 0
	.DB 	0b00100000, 0b01001000	; 0 and b
	.DB 	0b01101110, 0b00001100	; I and E
	.DB 	0b00001001, 0b01111111	; S and .

So the first byte in the hex file (and hence flash of the AVR) would be part of the very first opcode at:

INIT:
	LDI 	R16, HIGH(RAMEND) 	

Unless BOOTRST is used an AVR will typically fetch the first opcode at power on from location 0x0000 so you want to be pretty sure there's a valid opcode to get things started there.

As the location of the interrupt vectors are fixed (right after the opcode at 0) then if you do plan to use interrupts your very first opcode is likely to be RJMP or JMP to jump over the interrupt vectors. In which case you might want:

; ** Initialize program:
INIT:

	; Initiate Stack

	LDI 	R16, HIGH(RAMEND) 	

to actually be:

    .org 0
    RJMP INIT

; insert interrupt vectors here if they are to be used later    
    
; ** Initialize program:
INIT:

    ; Initiate Stack

    LDI 	R16, HIGH(RAMEND) 	
etc.